Kirmse: Beschreibung des Aufrufs korrigiert

2009-06-15T07:04:17Z

Beschreibung des Aufrufs korrigiert

← Nächstältere Version		Version vom 15. Juni 2009, 09:04 Uhr
Zeile 3:		Zeile 3:
	* Dieses Script dient dazu, in einer der Delixs-Gruppen hadmin, cadmin, tadmin, fachl, material, online und internet Lehrer (User) einzutragen.		* Dieses Script dient dazu, in einer der Delixs-Gruppen hadmin, cadmin, tadmin, fachl, material, online und internet Lehrer (User) einzutragen.

	* Parameter: -help oder -h, -user oder -u, -group oder -g		* Parameter: --help oder -h, --user oder -u, --group oder -g

	* Aufruf: delixs-groupadd -g hadmin -u mmustermann		* Aufruf: delixs-groupadd -g hadmin -u mmustermann

Kirmse: Script zum Eintragen von Usern in Delixs-Gruppen

2009-06-15T06:50:13Z

Script zum Eintragen von Usern in Delixs-Gruppen

Neue Seite

== delixs-groupadd ==

* Dieses Script dient dazu, in einer der Delixs-Gruppen hadmin, cadmin, tadmin, fachl, material, online und internet Lehrer (User) einzutragen.

* Parameter: -help oder -h, -user oder -u, -group oder -g

* Aufruf: delixs-groupadd -g hadmin -u mmustermann

==== das Script ====

<source lang="perl">

#!/usr/bin/perl
use warnings;
use strict;

use Net::LDAP;
use Getopt::Long;

my ($ldap, $ldap_base, $pass, $entry, @entries, $mesg, $gid, $group,
$member, @members, $anzahl, @groups);

@groups = qw(hadmin cadmin tadmin fachl material online internet);

# Initialisieren der Variablen fuer die Parameter
$member = '';
$group = '';

# wir holen uns zuerst die Parameter,
# falls --help, dann Ausgabe der Hilfe (siehe &help) und beenden
GetOptions('user=s' => \$member,
'group=s'=> \$group,
'help' => \&help);

# Wenn kein Parameter -u oder --user uebergeben wurde, dann Abbruch
if ($member eq '') {
die "Abbruch: es wurde kein Loginname uebergeben!\n";
}

# Wenn kein Parameter -g oder --group uebergeben wurde, dann Abbruch
if ($group eq '') {
die "Abbruch: es wurde keine Gruppe uebergeben!\n";
}

# Der Parameter -g muss in @groups aufgelistet sein
$anzahl = grep /^$group$/, @groups;
if ( $anzahl == 0) {
die "Abbruch: $group ist keine Delixs-Gruppe!\n";
}

# Wenn wir keine root-Rechte haben, dann Abbruch
if ($> != 0) { # siehe $EFFECTIVE_USER_ID,$EUID
die "Abbruch: das Script muss mit root-Rechten ausgefuehrt werden!\n";
}

# wir holen uns die Such-Basis ($ldap_base) aus der ldap.conf
open DATEI, '<', '/etc/ldap/ldap.conf'
or die "Abbruch: konnte ldap.conf nicht oeffnen, $!\n";
while (my $zeile = <DATEI>) {
if ($zeile =~ m/^\s*base\s+(\w.*\w)\s*$/i) {
$ldap_base = $1;
last;
}
}
close DATEI;

# da wir (spaeter) in den LDAP schreiben wollen, brauchen wir noch das Passwort
open DATEI, '<', '/etc/ldap.secret'
or die "Abbruch: konnte ldap.secret nicht oeffnen, $!\n";
$pass = <DATEI>;
chomp($pass);
close DATEI;

# wir verbinden uns mit dem LDAP
$ldap = Net::LDAP->new('127.0.0.1', version => 3) or die "Abbruch: $@";
$ldap->bind( dn => "cn=admin, $ldap_base", password => $pass)
or die "Abbruch: konnte mich nicht mit dem LDAP verbinden";

# Wir ueberpruefen, ob der Parameter -u ein gueltiges Login ist
$mesg = $ldap->search(base => "ou=people,ou=accounts,$ldap_base",
filter => "uid=$member",
attrs => ['uid', 'gidNumber'] );
# wenn Fehlercode, dann das Script mit Fehlermeldung sterben lassen
$mesg->code and die $mesg->error;
# Wenn der uebergebene Parameter kein User ist, dann Abbruch
if (scalar ($mesg->entries) == 0) {
die "Abbruch: $member ist kein gueltiger Account!\n";
}

# Wenn der uebergebene Parameter kein Lehrer ist, dann Abbruch
# diesen Test bei 'online' und 'internet' nicht machen
unless (($group eq 'online') or ($group eq 'internet')) {
$entry = ($mesg->entries)[0]; # nur ein Element in der Liste
$gid = $entry->get_value('gidNumber'); # die GID von $newmember holen
if ( $gid != 1001) {
die "Abbruch: $member ist kein Lehrer!\n"; # ungleich 1002, dann Abbruch
}
}

#wir suchen in der Gruppe, ob es schon einen Eintrag fuer $member gibt
$mesg = $ldap->search(base => "cn=$group,ou=groups,$ldap_base",
filter => "cn=$group",
attrs => ['memberUid'] );
$entry = ($mesg->entries)[0]; # nur ein Element in der Liste
@members = $entry->get_value('memberUid');
$anzahl = grep /^$member$/, @members;
if ( $anzahl > 0) {
die "Abbruch: $member ist schon in der Gruppe $group!\n";
}

# wir fuegen dem Entry einen weiteren Eintrag fuer memberUid hinzu
$mesg = $ldap->modify( "cn=$group,ou=groups,$ldap_base",
add => { memberUid => [ $member ] } );
# wenn Fehlercode, dann das Script mit Fehlermeldung sterben lassen
$mesg->code and die $mesg->error;

# wir trennen uns vom LDAP
$ldap->unbind;

# Ausgabe auf der Konsole (Rueckmeldung)
print "User $member wurde in die Gruppe $group eingetragen.\n";

################### Programm-Ende #####################################

# Wenn Parameter -h uebergeben wurde, dann Hilfe ausgegeben und beenden
sub help
{
print "Hilfe muss noch erstellt werden.\n";
exit (0);
}

__END__

</source>

Benutzer:Kirmse/delixs-groupadd - Versionsgeschichte

Kirmse: Beschreibung des Aufrufs korrigiert

Kirmse: Script zum Eintragen von Usern in Delixs-Gruppen